[Article] Nero 7 released, but a fizzer

Nero 7 is now available. A trial demo is available for free download. I downloaded it today to see what was new.

I had been looking forward to this release but was very disappointed. Almost all the changes are superficial changes to the “skin”. There appeared to only be two new features. There is a lack-lustre addition of Blue-ray disc support, but it seems to only support the basic file system, no video features. The other addition appears to be some TV tuner card app that can watch and record shows from TV. This is probably a useful program, but I have not got a tuner card so I couldn’t do much with it.

Nero Vision is now called Nero Vision 4, but hardly deserves a full version number increase as it is the same as as the Nero vision 3. It appears to have inherited the same problem as 3.1.0.14 and 3.1.0.16. A 41 minute AVI file was going to take 2 hours 20 minutes to encode to a DVD. The same settings with 3.1.0.11 took 1 hour.

There appears to be no justification to calling this new version Nero 7, rather than just a minor version increase with version 6. I expect it is has been driven by marketing. Nero want to release a full new version so they can resell the same product back to people who already have it, rather than them just getting a free upgrade.

So my recommendation is to use Nero 6.6.0.16 with Nero Vision 3.1.0.11 (From the Nero 6.6.0.14 distribution)

 

[Gadgets] Sony Ericsson P990 Announced

 

 

Finally after so many rumors and leaked images of Sony Ericsson’s new PX00 they have offically announced the P990 . This smart phone has a bunch of features but what stood out to me were the 2 megapixel camera, bluetooth and 802.11b, mp3 and fm radio, mpeg-4 player and it is all powered by Symbian OS 9.1. I do not own any of the earlier PX00 products and I have not had any experience with the Symbian OS, but my Father loves his P800. Interestingly it is also running Opera 8.0.

 

 

[News] From Todays Browsing

• For all you Knoppix fans version 4.0.2 has just been released. For those of you that are not familiar with Knoppix here is the Wikipedia link. Knoppix is a Linux LiveCD distrubution. Recently I have been trying out The Auditor security collection which is a LiveCD distribution based on Knoppix. It has been designed with a menu structure that groups the various tools into the various phases of a security audit, foot-printing, analysis, scanning, wireless, brute-forcing, cracking. It also includes a very comprehensive collection of wifi and bluetooth tools.
  

• The Inquirer is reporting that Microsoft lost over $US 4 billion over 4 years from the Xbox. Even more interesting is that they expect to loose money on the Xbox 360 as well and this is all part of the plan to gain a strong foothold in the lucrative console market.

• Microsoft have released Service Pack 2 (KB887979) for Office 2003, it is a compilation of all previous updates as well as containing “some significant security enhancements”. There are two versions of the Service Pack, Office2003SP2-KB887616-Client-ENU.exe (51Mb) might require whereas the Office2003SP2-KB887616-FullFile-ENU.exe (104Mb) will not.
  

• Tom’s Hardare Guide has a great comparison of 22 Serial ATA and Ultra ATA Hard Drives which is worth a read, I was just happy to see that my 74 GB Raptor from Western Digital came up tops for performance. I use this 10,000 rpm SATA drive for my OS, applications and of course games. I have had this drive for a year now and I do notice the performance when the booting my OS and loading games and applications.

[Application] Power Supply Wattage Calculator

If you have ever upgraded your computer or built your own then I am sure you have always wondered how much power is enough. This great web based application Power Supply Calculator solves this problem.

You begin by choosing your CPU, which start with the AMD K6 166MHz and the Intel Pentium MMX 166MHz up to the latest releases for both Brands. Then you select your Graphics Card, Memory, Hard Drives, Optical drives then all your PCI cards, modems, the number of USB and Firewire Devices and then any fans and lights you might have. Then it adds up the wattage for all these components.

I did this manually when building my current PC going to all the manufacture sites looking for the details I needed, this took sometime. I will be using this for certain on my next build or major upgrade.

Since we are on the topic of power supplies I thought I would mention the power supply I have Antec’s NeoPower 480.

This power supply rocks in so many ways the apart from the beautiful silence to the high performance and stability for overclocking, its most noticeable feature is the “Advanced Cable Management System” which is a set of modular cables, allowing you to only have connected those cables you need, reducing congestion inside your case which results in better airflow.

Though more expensive than the “free” power supplies that a lot of cases come with, if you are building a machine for performance or stability then spending the extra money on power supply is definitely worth it. You can get all sorts of weird problems occurring if you dot not have enough power and cheap branded power supplies are not known for their stability and their output spikes and dips and there is nothing worse than just lining up a headshot or a perfect ganking and having your machine start to play up.

[Article] Integrating (Slipstreaming) Hotfixes for Windows XP and 2003

If you read my previous article you will have a nice off-line method for installing all the latest hot-fixes for Windows XP and 2003. This will mean you could reinstall your OS and then apply the hot-fixes without having to go online. This saves time but we can take it one step further and save even more time. How about making a new Windows CD that has all the hot-fixes already integrated? This will install a fully up-to-date Windows right from the CD.

I will provide a guide in this article how to make a CD for Windows XP and for Windows Server 2003. You can apply similiar techniques for Windows 2000, and also the 64 bit editions but I won’t detail them here.

What you need:

• An existing Windows XP or Windows 2003 installation CD. If you haven’t got one then the rest of the article will be useless to you! If your computer only came with rescue CDs (typical for most OEM versions) then you are stuck too.
• CD Writing software such as Nero. The built in XP one will not make a bootable CD.
• Windows XP Service pack 2, or Windows 2003 Service Pack 1. Go here to get download links for the service packs.
• The 32 hot-fixes for XP, or 13 hot-fixes for 2003. Go here to get the download list of the hot-fixes.
• The Boot image of the CD. You can use IsoBuster in free mode to read the boot image

So if you have all these you can follow the next instructions.

Copy the CD to hard disc

Copy the contents of the Windows CD to a directory on your hard disc. For the rest of the article I will use the locations C:\XP and C:\2003 for the locations the files were copied. There should be a directory called I386 which is off the root of the CD. If this is not the case then you probably have some multi boot CD such as an MSDN one, this requires a little bit more work as the directory references will be wrong.

A quick guide for MSDN discs: Copy the directory that looks like the image you want (eg the 2003 CD probably has Standard Edition, and Enterprise Edition on the same disc, there will be an obvious directory). Ignore the high level directories, you want the big one that contains I386. There is a text file you need to edit which I believe is txtsetup.sif. There is a line in there that says something about SourceDirectory which will contain the original path on the CD, change this to “\”. You will also need to get hold of a plain Windows CD Boot Image.

Get boot image of CD

Use IsoBuster to read the boot image off the CD. It is generally called “Microsoft Corporation.img”. You might want to rename the extension to .ima for Nero (newer versions use .ima, older use .img). Note: If you have used an MSDN multi boot CD, then you need to get a CD boot image that only has one OS version on it. If you have MSDN you are will have a CD that fits the bill. It can be any XP or 2003 CD, the boot image is all the same.

Note: you don’t have to pay for IsoBuster. It has a free mode which has reduced features. The feature of reading the boot image is free. Sadly you can’t use Nero to read the boot image, this is the only thing that Nero doesn’t do when it comes to CDs and DVDs. A pity.

Make sure you have a directory with the files you need

I am assuming you have downloaded the Service Pack files you need and all the hot-fixes. Lets say you have put them in the directory C:\Dump.

Integrate the Service Pack

I am assuming your CD was a Base version of XP or 2003. You may have one that already has the Service pack in it (eg if the CD says: “Windows XP Professional with Service Pack 2” then this bit is already done for you!).

Now run cmd (ie a command shell window). Make sure you are in the directory C:\Dump.

For Windows XP run
WindowsXP-KB835935-SP2-ENU.exe /integrate:C:\XP

For Windows 2003 run
WindowsServer2003-KB889101-SP1-x86-ENU.exe /integrate:C:\2003

These operations will take a while to run, hopefully they will say success at the end.

Integrate the hot-fixes for Windows 2003

There are only 13 of these hot-fixes at the moment and they are straight forward. For each hot-fix use the command line:
/integrate:C:\2003 /passive

The passive flag means it won’t prompt you. I recommend using a batch file. Create a batch file with the following lines in it:

WindowsServer2003-KB896422-x86-enu.exe /integrate:C:\2003 /passive
WindowsServer2003-KB896358-x86-enu.exe /integrate:C:\2003 /passive   
WindowsServer2003-KB890046-x86-enu.exe /integrate:C:\2003 /passive
WindowsServer2003-KB896428-x86-enu.exe /integrate:C:\2003 /passive
WindowsServer2003-KB883939-x86-enu.exe /integrate:C:\2003 /passive
WindowsServer2003-KB898792-v2-x86-enu.exe  /integrate:C:\2003 /passive
WindowsServer2003-KB903235-x86-ENU.exe /integrate:C:\2003 /passive
WindowsServer2003-KB901214-x86-ENU.exe /integrate:C:\2003 /passive
WindowsServer2003-KB893756-x86-ENU.exe /integrate:C:\2003 /passive
WindowsServer2003-KB899591-x86-ENU.exe /integrate:C:\2003 /passive
WindowsServer2003-KB899587-x86-ENU.exe /integrate:C:\2003 /passive
WindowsServer2003-KB896727-x86-ENU.exe /integrate:C:\2003 /passive
WindowsServer2003-KB899588-x86-ENU.exe /integrate:C:\2003 /passive

Put the batch file in the directory with the hot-fixes and run it.

Integrate the hot-fixes for Windows XP

This is harder than for 2003. There are currently 32 hot-fixes since SP2 for XP. There are two hot-fixes that conflict with each other

The problem hot-fixes are KB885835 and KB885250. The issue here is that they both try to update the file mrxsmb.sys, and the integration process does not like this. KB885835 only changes mrxsmb.sys with a version older than KB885250, so it completely superseded by KB885250. However if you don’t install it then windows update will see you haven’t got it and will say you require an update. If you do the update it will apply the hot-fix, but not actually replace the mrxsmb.sys file as the version currently on will be later anyway. So what will actually be applied? Nothing except the registry entries to say that the hot-fix is applied!

We can achieve the same thing in integration. We can get both hot-fixes “integrated”, however KB885835 will only be there in name, its one file already superseded by KB8825250.

KB885835 should be integrated first, then the file C:\XP\I386\svcpack\HFINT.DAT must be edited. The line that says mrxsmb.sys should be modified to something else, for example: mrxsmb.sys.temp. Then KB885250 can be integrated. The line in HFINT.DAT should be changed back to the original again. The remaining 30 hot-fixes can be integrated without problem.

To integrate a hot-fix the syntax is the same as for 2003:
/integrate:C:\XP /passive

Once again I recommend a batch file. Especially as we can automate the tweaking of HFINT.DAT.

Put the following into a batch file (I called it IntegrateAll.bat). Execute the batch file with the command:
IntegrateAll C:\XP

@Echo off
rem ////////////////////////////////////////////////////////////////////////////
rem // IntegrateAll.bat
rem // This Batch file integrates the hotfixes for Windows XP SP2
rem // Syntax:
rem //   IntegrateAll <DistributionFolder>
rem ////////////////////////////////////////////////////////////////////////////

if "%~1" == "-p" goto Process

rem ////////////////////////////////////////////////////////////////////////////
rem // Main routine
rem // %1 contains Options
rem //

rem //
rem // Verify that we are pointing to a distribution folder base
rem //
if exist "%~1\I386" goto FolderExists

echo -- "%~1" is not a distribution folder.
echo Syntax:
echo   IntegrateAll ^<DistributionFolder^>
goto END

:FolderExists

echo ::: Integrating Updates :::

set DISTDIR="%~1"
set HFINT="%~1\i386\svcpack\HFINT.DAT"
set HFINTTEMP="%~1\i386\svcpack\HFINT.TMP"

rem //
rem // Do 885835 and then 885250 to start with. There is a conflict here. So
rem // we need to do some special processing. Note: 885835 is superceeded by
rem // 885250 but we want an entry so that the hotfix show as installed
rem //
call %0 -p KB885835 "WindowsXP-KB885835-x86-ENU.exe"

rem // Modify the line mrxsmb.sys (change it to mrxsmb.sys.tmp)
for /f "usebackq" %%L in (%HFINT%) DO (
 if %%L==mrxsmb.sys (
  echo %%L.tmp>>%HFINTTEMP%
 ) else (
  echo %%L>>%HFINTTEMP% )
)
move /y %HFINTTEMP% %HFINT% > NUL

rem // Integrate 85250 
call %0 -p KB885250 "WindowsXP-KB885250-x86-ENU.exe"

rem // Modify the line back (change the mrxsmb.sys.tmp back to mrxsmb.sys)
for /f "usebackq" %%L in (%HFINT%) DO (
 if %%L==mrxsmb.sys.tmp ( 
  echo mrxsmb.sys>>%HFINTTEMP%
 ) else (
   echo %%L>>%HFINTTEMP%
 )
)
move /y %HFINTTEMP% %HFINT% > NUL

rem //
rem // Now integrate all the rest of the hotfixes.

call %0 -p KB888302 "WindowsXP-KB888302-x86-ENU.exe"
call %0 -p KB887472 "WindowsXP-KB887472-x86-enu.exe"
call %0 -p KB891781 "WindowsXP-KB891781-x86-ENU.exe"
call %0 -p KB888113 "WindowsXP-KB888113-x86-ENU.exe"
call %0 -p KB867282 "WindowsXP-KB867282-x86-ENU.exe"
call %0 -p KB873333 "WindowsXP-KB873333-x86-ENU.exe"
call %0 -p KB890175 "WindowsXP-KB890175-x86-ENU.exe"
call %0 -p KB886185 "WindowsXP-KB886185-x86-enu.exe"
call %0 -p KB885836 "WindowsXP-KB885836-x86-ENU.exe"
call %0 -p KB873339 "WindowsXP-KB873339-x86-ENU.exe"
call %0 -p KB887742 "WindowsXP-KB887742-x86-ENU.exe"

call %0 -p KB883939 "WindowsXP-KB883939-x86-ENU.exe"
call %0 -p KB890046 "WindowsXP-KB890046-x86-ENU.exe"
call %0 -p KB890859 "WindowsXP-KB890859-x86-ENU.exe"
call %0 -p KB893066 "WindowsXP-KB893066-v2-x86-ENU.exe"
call %0 -p KB893086 "WindowsXP-KB893086-x86-ENU.exe"
call %0 -p KB896358 "WindowsXP-KB896358-x86-ENU.exe"
call %0 -p KB896422 "WindowsXP-KB896422-x86-ENU.exe"
call %0 -p KB896428 "WindowsXP-KB896428-x86-ENU.exe"
call %0 -p KB898461 "WindowsXP-KB898461-x86-ENU.exe"
call %0 -p KB903235 "WindowsXP-KB903235-x86-ENU.exe"
call %0 -p KB901214 "WindowsXP-KB901214-x86-ENU.exe"
call %0 -p KB893803v2 "WindowsInstaller-KB893803-v2-x86.exe"
call %0 -p KB896727 "WindowsXP-KB896727-x86-ENU.exe"
call %0 -p KB899587 "WindowsXP-KB899587-x86-ENU.exe"
call %0 -p KB894391 "WindowsXP-KB894391-x86-ENU.exe"
call %0 -p KB899588 "WindowsXP-KB899588-x86-ENU.exe"
call %0 -p KB896423 "WindowsXP-KB896423-x86-ENU.exe"
call %0 -p KB899591 "WindowsXP-KB899591-x86-ENU.exe"
call %0 -p KB893756 "WindowsXP-KB893756-x86-ENU.exe"

echo.
echo ::: Done :::
echo.

goto END

rem ////////////////////////////////////////////////////////////////////////////
rem ////////////////////////////////////////////////////////////////////////////
:Process
rem //
rem // %2 will contain the KB number
rem // %3 will contain the Exe file name
rem //

echo Integrating %2
"%~3" /integrate:%DISTDIR% /passive

:EndProcess
goto END

rem ////////////////////////////////////////////////////////////////////////////

:END

Write the CD

I recommend Nero however you should be able to use other packages to achieve the same thing. I recommend you put a copy of the Microsoft Corporation.ima Boot image file in the C:\XP and C:\2003 directories. This way you don’t have to extract it next time you want to add some more hotfixes.

Create a “Bootable CD”. Use “Microsoft Corporation.ima” as the Image File. Then select Expect features (This is important otherwise you will end up with a non bootable CD) and choose “No emulation” (in the section “Kind of emulation”. For “Number of loaded Sectors” choose 4. The “Load segment of sectors” default of “07C0” should be left.

Put the directory contents of C:\XP or C:\2003 in the root of the CD image. Choose a sensible volume label (Try to indicate SP and the number hot-fixes, its hard because you only get 16 characters. I use things like XP_PRO_SP2_32HF and 2003ENT_SP1_13HF).

If you have Vmware I recommend writting this to a .iso file and trying it in Vmware, saves ruining a CD-R if you got something wrong.When you are happy write it to an actual CD-R and make sure you print on a beautiful label. Don’t go scribbling on with a felt pen, use a printable CD-R or print on a CD label and stick it on. Technically this is not required to integrate the hotfixes, but I don’t want to know of any ugly CD-Rs out there.

The Future

When new hot-fixes come out you can take the latest CD you have made, copy the files to hard disc, apply the new hot-fixes (with the /intergate option) and write a new CD-R.

I will update this article as new hotfixes come out.

 

[Article] Updating XP SP2 and 2003 SP1 Without using Windows Update

You may dislike using Windows Update. I personally dislike the idea of running things on my computer that connect to the Microsoft web site. You may also have difficulties using it these days since The Genuine Validation Advantage program was introduced. Or you may have computers that are not connected to the Internet. In addition, you may like to actually keep hold of an update so you don’t have to waste time down-loading it again next time. So if you fit in any of these categories, then this may help.

How do you know what updates to get? And where do you get them from. This is the tricky bit. MS does provide a way for Administrators to get updates which can be applied off-line, but they don’t make it terribly easy to figure out what ones you need. However you are in luck because it turns out that ben.run has already figured out what you need and is going to provide some useful links.

Note: Before we start I am assuming you are using Windows XP SP2 or Windows 2003 SP1. If you are not using these service packs then go and apply them now.

Windows XP Service Pack 2 Download
Windows 2003 Service Pack 1 Download

Now you will have the service pack for ever if you need to reinstall. To run the Service Pack just double click the .exe file and say yes. You will need to reboot when finished.

Okay now you want to be fully uptodate. Well as of today (10–September-2005) there are 32 updates for XP SP2 and 13 for 2003. Note: I am expecting MS to release new hot-fixes any day now, so this article will be updated and reposted when that happens.

First you need to download them all. However to run them all one by one is very tedious as each one requires things to be clicked. However this can be scripted so you only need to run one thing and it will see what ones are currently not installed and will install them in one go. I have a script for this which I’ll get to soon. But right now lets make sure you get the files. Now you find all these files based on their KB numbers from Microsoft, but that is tedious. So I have done the tedious work for you and provided direct links to the files on the Microsoft site. Note however the URLs contain large sets of numbers in them which Microsoft may change in the future just to be a pain. They work as of now, if they don’t work in the future you’ll just have to use the KB numbers and find them.

32 Critical Updates for Windows XP SP2 to 10–September-2005

KB885250
KB888302
KB885835
KB887472
KB891781
KB888113
KB867282
KB873333
KB890175
KB886185
KB885836
KB873339
KB887742
KB883939
KB890046
KB890859
KB893066
KB893086
KB896358
KB896422
KB896428
KB898461
KB903235
KB901214
KB893803v2
KB896727
KB899587
KB894391
KB899588
KB896423
KB899591
KB893756

13 Critical Updates for Windows 2003 SP1 to 10–September-2005

KB896422
KB896358
KB890046
KB896428
KB883939
KB898792
KB903235
KB901214
KB893756
KB899591
KB899587
KB896727
KB899588

Right now you have all the files for the critical updates. You could run each one individually, but that will be boring. Each one can be called with command line options. I use the options “/passive /norestart /nobackup”. This means don’t ask for interaction but show what is going on, don’t reboot, and don’t bother backing up the old files. You only need to reboot at the very end.

Unfortunately MS has changed the command line parameters. /nobackup used to be /n. You can still use the /n switch on the newer ones though.

So here are the two batch files I have which will apply the hot-fixes. The batch files will check to see if the patch is already installed before running it. This speeds up the process greatly for machines with some of the patches already loaded.

Batch file for installing 32 XP SP2 Hot-fixes.

Copy the text out and call it Setup.bat

@Echo off
rem ////////////////////////////////////////////////////////////////////////////
rem // Setup.bat
rem // This Batch file runs the hotfixes for Windows XP SP2
rem // If the hotfix is already installed (checked by looking for reg key)
rem // then the installation is skipped.
rem ////////////////////////////////////////////////////////////////////////////

if "%~1" == "-p1" set Flags=/passive /norestart /n & goto Process
if "%~1" == "-p2" set Flags=/passive /norestart /nobackup & goto Process

rem ////////////////////////////////////////////////////////////////////////////

set RegKey=HKLM\Software\Microsoft\Updates\Windows XP\SP3

rem ////////////////////////////////////////////////////////////////////////////
rem // Main routine
rem // %1 contains Options
rem //

color 17
title Windows XP SP2 - 32 Hotfixes

echo ::: Installing Updates :::
echo.

call %0 -p1 KB885250 "WindowsXP-KB885250-x86-ENU.exe"
call %0 -p1 KB888302 "WindowsXP-KB888302-x86-ENU.exe"
call %0 -p1 KB885835 "WindowsXP-KB885835-x86-ENU.exe"
call %0 -p1 KB887472 "WindowsXP-KB887472-x86-enu.exe"
call %0 -p1 KB891781 "WindowsXP-KB891781-x86-ENU.exe"
call %0 -p1 KB888113 "WindowsXP-KB888113-x86-ENU.exe"
call %0 -p1 KB867282 "WindowsXP-KB867282-x86-ENU.exe"
call %0 -p1 KB873333 "WindowsXP-KB873333-x86-ENU.exe"
call %0 -p1 KB890175 "WindowsXP-KB890175-x86-ENU.exe"
call %0 -p1 KB886185 "WindowsXP-KB886185-x86-enu.exe"
call %0 -p1 KB885836 "WindowsXP-KB885836-x86-ENU.exe"
call %0 -p1 KB873339 "WindowsXP-KB873339-x86-ENU.exe"
call %0 -p1 KB887742 "WindowsXP-KB887742-x86-ENU.exe"

call %0 -p2 KB883939 "WindowsXP-KB883939-x86-ENU.exe"
call %0 -p2 KB890046 "WindowsXP-KB890046-x86-ENU.exe"
call %0 -p2 KB890859 "WindowsXP-KB890859-x86-ENU.exe"
call %0 -p2 KB893066 "WindowsXP-KB893066-v2-x86-ENU.exe"
call %0 -p2 KB893086 "WindowsXP-KB893086-x86-ENU.exe"
call %0 -p2 KB896358 "WindowsXP-KB896358-x86-ENU.exe"
call %0 -p2 KB896422 "WindowsXP-KB896422-x86-ENU.exe"
call %0 -p2 KB896428 "WindowsXP-KB896428-x86-ENU.exe"
call %0 -p2 KB898461 "WindowsXP-KB898461-x86-ENU.exe"
call %0 -p2 KB903235 "WindowsXP-KB903235-x86-ENU.exe"
call %0 -p2 KB901214 "WindowsXP-KB901214-x86-ENU.exe"
call %0 -p2 KB893803v2 "WindowsInstaller-KB893803-v2-x86.exe"
call %0 -p2 KB896727 "WindowsXP-KB896727-x86-ENU.exe"
call %0 -p2 KB899587 "WindowsXP-KB899587-x86-ENU.exe"
call %0 -p2 KB894391 "WindowsXP-KB894391-x86-ENU.exe"
call %0 -p2 KB899588 "WindowsXP-KB899588-x86-ENU.exe"
call %0 -p2 KB896423 "WindowsXP-KB896423-x86-ENU.exe"
call %0 -p2 KB899591 "WindowsXP-KB899591-x86-ENU.exe"
call %0 -p2 KB893756 "WindowsXP-KB893756-x86-ENU.exe"

echo.
echo ::: Done :::

echo.
pause

goto END

rem ////////////////////////////////////////////////////////////////////////////
rem ////////////////////////////////////////////////////////////////////////////
:Process
rem //
rem // %2 will contain the KB number
rem // %3 will contain the Exe file name
rem // %4 will contain any options passed originaly
rem //

rem //
rem // See if the Reg key exists, this indicates whether patch has already
rem // been installed
rem //
reg query "%RegKey%\%2" > nul 2>&1
if errorlevel 1 goto NeedToInstall

echo %2 - Already Installed. Skipping.
goto EndProcess

:NeedToInstall
echo %2 - Installing
%3 %Flags%

goto EndProcess

:EndProcess
goto END

rem ////////////////////////////////////////////////////////////////////////////

:END

Batch file for installing 13 Windows 2003 SP1 Hotfixes.

Copy the text out and call Setup.bat

@Echo off
rem ////////////////////////////////////////////////////////////////////////////
rem // Setup.bat
rem // This Batch file runs the hotfixes for Windows 2003 SP1
rem // If the hotfix is already installed (checked by looking for reg key)
rem // then the installation is skipped.
rem ////////////////////////////////////////////////////////////////////////////

set Flags=/passive /norestart /nobackup

if "%~1" == "-p" goto Process

rem ////////////////////////////////////////////////////////////////////////////

set RegKey=HKLM\Software\Microsoft\Updates\Windows Server 2003\SP2

rem ////////////////////////////////////////////////////////////////////////////
rem // Main routine
rem // %1 contains Options
rem //

color 17
title Windows Server 2003 SP1 - 13 Hotfixes

echo ::: Installing Updates :::
echo.

call %0 -p KB896422 "WindowsServer2003-KB896422-x86-enu.exe"
call %0 -p KB896358 "WindowsServer2003-KB896358-x86-enu.exe"
call %0 -p KB890046 "WindowsServer2003-KB890046-x86-enu.exe"
call %0 -p KB896428 "WindowsServer2003-KB896428-x86-enu.exe"
call %0 -p KB883939 "WindowsServer2003-KB883939-x86-enu.exe"
call %0 -p KB898792 "WindowsServer2003-KB898792-v2-x86-enu.exe"
call %0 -p KB903235 "WindowsServer2003-KB903235-x86-ENU.exe"
call %0 -p KB901214 "WindowsServer2003-KB901214-x86-ENU.exe"
call %0 -p KB893756 "WindowsServer2003-KB893756-x86-ENU.exe"
call %0 -p KB899591 "WindowsServer2003-KB899591-x86-ENU.exe"
call %0 -p KB899587 "WindowsServer2003-KB899587-x86-ENU.exe"
call %0 -p KB896727 "WindowsServer2003-KB896727-x86-ENU.exe"
call %0 -p KB899588 "WindowsServer2003-KB899588-x86-ENU.exe"

echo.
echo ::: Done :::

echo.
pause

goto END

rem ////////////////////////////////////////////////////////////////////////////
rem ////////////////////////////////////////////////////////////////////////////
:Process
rem //
rem // %2 will contain the KB number
rem // %3 will contain the Exe file name
rem // %4 will contain any options passed originaly
rem //

rem //
rem // See if the Reg key exists, this indicates whether patch has already
rem // been installed
rem //
reg query "%RegKey%\%2" > nul 2>&1
if errorlevel 1 goto NeedToInstall

echo %2 - Already Installed. Skipping.
goto EndProcess

:NeedToInstall
echo %2 - Installing
%3 %Flags%

goto EndProcess

:EndProcess
goto END

rem ////////////////////////////////////////////////////////////////////////////

:END

Now make sure the Setup.bat file is in the same directory as all the Hotfixes files (the .exe files you downloaded). You can simply run the the batch file by clicking on it.

Wrapping it up into one nice package

Now you can put the directory with the hotfixes and the setup.bat file into a self extracting archive. For example I use WinRar. First create a .RAR or .ZIP file of the directory. Then make an SFX with the setup command “Setup.bat”.

So now you have a single .exe file (or two if you made both the 2003 version and the XP version). which you can take to any computer and simply run. This will make sure it has all the updates. The batch file checks to see if it is a hotfix is already installed before attempting to install it.

* Article Update: I have found a better link for KB887742, so the file name does not need renaming.

[General] Blog Update

Some exciting news is my good friend Ben from ben.run has decided to join the nzgadet team and is going to offer some of his technical wisdom to this blog.  I know that his articles and comments will definitely be worth a read. 

I have some good articles in the pipeline at the moment which I will finish up over the weekend.  One of the more interesting articles is about a recent Wardrive I went on, in which we discovered 824 wireless Access Points (AP) around the CBD in Wellington, New Zealand.  If you go to WiGLE and zoom in on Wellington, New Zealand you will see all the data I uploaded there, 770 of the AP’s that we discovered had not been posted to WiGLE  before so they are now up there.  You do need to zoom right in to see all the details.  More on all of this later…

If you will be checking this blog in the future and are using Firefox then you should get the extension Sage which I mentioned in a previous post. If you are reading this blog from Microsofts Internet Explorer then you should look at using Firefox.

[Gadget] World's First Linux Keyboard

Zerone sent me this link to what is purported to be the Worlds First Linux keyboard  where the Windows Start key is replaced with a little picture of a Penguin, known as Tux, which is the linux logo.  I dont think we will start to see two of every keyboard coming out, maybe they might ship new keyboards with two keys and you can customise it to your preference but until then at least the true die hard linux fans now have their very own keyboard.

 

[Applications] Tabs in IE Now

Foixe is a plug-in for Internet Explorer that has been designed with two things in mind. Firstly they want to give IE the look and feel of Firefox , so to do this they have added Tabs, a Search Bar and GroupMarks to IE.  The search bar uses the AskJeeves search engine and I saw no quick way to change this to google.

Secondly they describe Foxie as a Complete Privacy, Security and Productivity Suite with Ad Blocking, Popup blocking, Flash blocking, Privacy Cleaner, Firewall, Spyware remover etc etc.

It will be interesting to see if this will take off.  I personally use the open source browser Firefox and really like it, its simple clean functional and with Firefox Extensions fully customisable. It also runs on Windows, OS-X and Linux.

If you have not tried Firefox then you should definitely give it a try.  In Firefox you use extensions to add extra functionality.  Here are a list of the main extensions I use:

• BugMeNot – A simple right click brings up this menu option which will check the BugMeNot database for a known username and password for the current site, this is great for sites like Time Magazine which often require you to sign up to see the full article but offer free logins. 
• Sage – A great way to stay on top of all your blogs you check.  When you visit your blogs and favourite websites you can check them for RSS and Atom Feeds. Sage can then be manually refreshed or automatically configured to go and check these sites for you and will conveniently show you in bold any of the sites that have been updated since your last visit.  This save having to visit a site just to check for any new content.  Sage is also a reader and will display the feeds for you.
• IE View– This provides a right-click menu option which opens the page up in Internet Explorer.  Some websites are developed with poor coding standards and are better viewed in IE this helps with that.
• Image Zoom – This provides a right-click menu option which you can zoom in and out of images in a page.
• AdBlock – A customisable Ad Blocker
• BlogJetThis – I want to write more about BlogJet and this extension in another article

Those are the most common extensions I use.  On writing this article I notice that there are a lot of new extensions on Firefox Extensions Top Rated page so I must go see what is new.  But let me know what are your must have extensions for Firefox.

[NEWS] Blast from the Past

The guys over at Engadget have posted this article from their BBS from 1985. The articles are awesome to read and for some of you will undoubtedly cause a bit of nostalgia. I wonder how we will look back on our blogs of today in 20 years time.

For those of you too young to know what a BBS (Bulletin Board System) was it is what we had before the internet.  You dialed your modem directly into the BBS’s modem bank.  I still remember when my local BBS got a second phone line, which meant two people could be online at once and we could chat real time it was amazing!